Примеры скриптов PECMD.

//---Install GUI-------------------------------------------------------
CALL @Win1
ENVI MNTDIR=
ENVI WIMFILE=
ENVI $OEM$=
_SUB SetEdit4
ENVI Wimfile=
BROW Wimfile,install.wim,Пожалуйста выберите образ в папке sources *.wim;*.esd;*.swm который будет применен,wim;esd;swm|*install*.wim;*install*.esd;*install*.swm|All files|*.*|,0x1000
FIND $%WIMFILE%=,!ENVI @Win1_List1=%WIMFILE%
FDIR ypath=%WIMFILE%
ifex %ypath%\$OEM$, team envi @Win1_chek1.enable=1| envi @Win1_chek1.check=1! team envi @Win1_chek1.enable=0| envi @Win1_chek1.check=0
call llj "%WIMFILE%"
_END
_SUB SetWin1_Edit1
BROW $OEM$,*%Win1_Edit1%,Пожалуйста выберите папку $OEM$ в папке sources
FIND $%$OEM$%=,!ENVI @Win1_Edit1=%$OEM$%
FDIR oem=%$OEM$%
ifex %oem%\$OEM$, team envi @Win1_chek1.enable=1| envi @Win1_chek1.check=1! team envi @Win1_chek1.enable=0| envi @Win1_chek1.check=0
_END
_SUB FUN4
    envi WIMLIST=
    FORX \sources\*install.*,&&fd,0,TEAM# FDRV &&fp=%&fd%# FIND~ $X:=%&fp%, ~envi WIMLIST=%WIMLIST%%&fd%|
    TEAM envi @Win1_List1.VAL=%WIMLIST%
    MEMO MEMO1,L7T247W434H210,,,0x8
    TEAM envi @Win1_list3.VAL=1| envi @Win1_list3.SEL=1
    call llj "%Win1_List1%"
_END
_SUB FUN5
FDIR ypath=%Win1_List1%
ifex %ypath%\$OEM$, team envi @Win1_chek1.enable=1| envi @Win1_chek1.check=1! team envi @Win1_chek1.enable=0| envi @Win1_chek1.check=0
ifex %ypath%\$OEM$, team envi @Win1_Edit1=%ypath%\$OEM$| envi @Win1_Edit1=%ypath%\$OEM$! team envi @Win1_Edit1=| envi @Win1_Edit1=
call llj "%Win1_List1%"
_END
_SUB Apply
envi @Win1_item1.enable=0
ENVI Result=1
ENVI CheckIntegrity=
ENVI Compact=
FIND $%Win1_List1%=,TEAM ENVI Result=0|MESS Выберите образ Windows! @Error#OK
FIND $%Win1_List2%=,TEAM ENVI Result=0|MESS Выберите раздел для установки Windows! @Error#OK
FIND $%Result%=1,FIND $%Win1_Check2.Check%=1,ENVI CheckIntegrity=/CheckIntegrity
FIND $%Result%=1,FIND $%Win1_Check1.Check%=1,ENVI Compact=/Compact
FIND $%Result%=1,EXEC =CMD /C Dism /apply-image /imagefile:"%Win1_List1%" /index:%Win1_index% /ApplyDir:"%Win1_List2%" %CheckIntegrity% %Compact%
find $%Win1_chek1.check%=1, team file -progress %ypath%\$oem$\$$\*=>%panfu2%\windows| file -progress %ypath%\$oem$\$1\*=>%panfu2%
find $%Win1_chek1.check%=1, team file -progress %oem%\$oem$\$$\*=>%panfu2%\windows| file -progress %oem%\$oem$\$1\*=>%panfu2%
FIND $%Result%=1,call @Win2
envi @Win1_item1.enable=1
_END
_SUB Win1,W520H520,Установка Windows из *.wim;*.esd;*.swm,,PECMD.EXE#1
envi &::Win1_index=1
envi MEMO1=
FDRV AllDrive=
MEMO MEMO1,L7T247W500H210,,,0x8
GROU Win1_Group2,L7T6W500H235,Параметры установки Windows:
LABE Win1_Label,L15T27W120H30,Выберите install *.wim;*.esd;*.swm:
LIST Win1_List1,L140T32W230H24,,call FUN5
ITEM Win1_Button1,L375T31W70H26,Обновить,CALL FUN4
ITEM Win1_Button2,L450T31W50H26,Обзор,CALL SetEdit4
LABE Win1_Label2,L15T67W120H34,Выбрать раздел для установки Windows:
LIST Win1_List2,L140T72W40H35,%AllDrive%,TEAM envi panfu2=%Win1_List2%|envi @Win1_item1.enable=1
ITEM Win1_Button3,L190T71W130H26,Управление дисками,mmc.exe /b diskmgmt.msc
LABE Win1_Label3,L15T106W120H40,Выбрать индекс редакции Windows:
LIST Win1_List3,L140T111W40H20,1,envi Win1_index=%Win1_List3%,1
ITEM Button26,L190T110W90H26,WimInfo,EXEC* -code:866 -err+ @MEMO1=!cmd.exe /c Dism /get-wiminfo /wimFile:"%Win1_List1%" /index:%Win1_index% 2>&1
LABE Win1_Label4,L15T145W90H30,Выберите папку $OEM$:
EDIT Win1_Edit1,L140T151W230H24,
ITEM Win1_Button4,L375T150W50H26,Обзор,CALL SetWin1_Edit1
CHEK Win1_chek1,L430T152W70H22,$OEM$,,-2
LABE Win1_Label5,L15T188W130H20,Применить сжатие:
CHEK Win1_Check1,L140T188W150H20,Compact WIN 10/11
LABE Win1_Label6,L15T208W130H20,Во время установки:
CHEK Win1_Check2,L140T208W150H20,Проверять образ
ITEM Win1_item1,L294T190W100H35,1: УСТАНОВИТЬ,CALL Apply
ITEM Win1_Button5,L400T190W100H35,2: BcdBootGui,CALL Win2
    RADI RADI1,L30T460W143H18,,call fund,,
    ENVI ?disme=FVER,%WINDIR%\System32\dism.exe
    envi @RADI1=Dism %disme%
    RSTR disme1=5,%disme%
    LSTR disme2=3,%disme%
    envi disme=%disme2%%disme1%
    ENVI @RADI1.check=1
    //RADI RADI2,L180T460W140H20,,call funw,,
    //ifex "C:\Sources\wimlib-imagex.exe", EXEC*1 --hide &&wimn=C:\Sources\wimlib-imagex.exe --version! TEAM ENVI @RADI2.visable=0| ENVI @RADI1.check=1
    //MSTR &wimn=29,19,%&wimn%
    //SED  &wimn=1,[)], ,%&wimn%
    //envi @RADI2=%&wimn%
    ifex $%disme%>=6.317029,! TEAM envi @radi1.enable=1| envi @radi2.check=1| envi @name1:chek6.visable=0| envi @name2:chek1.visable=0| envi @name2:item6.visable=0| envi @name4:labe9.visable=1| envi @name3:Win2_CHEK1.visable=0
    ifex $%disme2%=10.,! envi @name3:chek8.visable=0
    envi @Win1_item1.enable=0
    //LABE LABE15,L415T465W14H17,?,notepad Install.txt,0xff0000,
    CALL @+ FUN4
_END
//Bcdboot_Gui
_SUB FIX
    TEAM ENVI @Win2_ITEM1=Обработка...| ENVI @Win2_ITEM1.Enable=0
    FIND $ =%Win2_List2%, !envi &&SPAN=/s %Win2_List2%
    FIND $ =%Win2_List3%, !envi &&GJ=/f %Win2_List3%
    FIND $%Win2_CHEK1.check%=1, envi &&bl=/d
    FIND $%Win2_CHEK2.check%=1, envi &&tj=/addlast
    EXEC* -code:866 -err+ &&jieg=!bcdboot.exe %Win2_List1% %&SPAN% %&GJ% %&bl% %&tj% /l %Win2_lan%
    mess+icon2 %&jieg%
    TEAM ENVI @Win2_ITEM1=Start| ENVI @Win2_ITEM1.Enable=1
_END
_SUB FUN1
    envi fDrive=
    FORX \Windows\system32\winload.exe,&&fd,0,TEAM# FDRV &&fp=%&fd%# FIND~ $X:=%&fp%, ~envi fDrive=%fDrive%%&fp%\Windows|
    FIND# $X=X%fDrive%, TEAM mess+icon1+top Не удалось найти системный раздел!
    LSTR &&sg=10,%fDrive%
    TEAM envi @Win2_List1.VAL=%fDrive%| envi @Win1_list1.SEL=%Win2_List1%\Windows
    KILL \
_END
_SUB FUN2
    FIND $ =%Win2_List2%, TEAM ENVI @Win2_List3.Enable=0| ENVI @Win2_List3.SEL= ! ENVI @Win2_List3.Enable=1
_END
_SUB FUN3
     EXEC* -code:866 -err+ &&jieg=!bcdboot.exe /?
     ENVI ?bcdv=FVER,%WinDir%\System32\bcdboot.exe
     mess+icon %&jieg% @bcdboot_релиз: %bcdv%
_END
_SUB Win2,W300H300,Bcdboot GUI,,,,, -disminb
    FDRV AllDrive=
    LIST Win2_List1,L90T30W105H75,
    LIST Win2_LAN,L100T59W68H100,cs-CZ|da-DK|de-DE|el-GR|en-US|es-ES|fi-FI|fr-FR|hu-HU|it-IT|ja-JP|ko-KR|nb-NO|nl-NL|pl-PL|pt-BR|pt-PT|ru-RU|sv-SE|tr-TR|uk-UA|zh-CN|zh-HK|zh-TW,,ru-RU,0x4
    GROU Win2_GROU1,L10T87W275H145,Другие варианты,
    LIST Win2_List2,L195T107W41H85,|%AllDrive%,call FUN2,%Win1_List2%
    CHEK Win2_CHEK1,L20T171W255H22,Сохранить существующую загр. запись, ENVI @Win2_CHEK2.Enable=1,
    CHEK Win2_CHEK2,L20T195W255H23,Добавить запись в конец,,
    ITEM Win2_ITEM1,L95T235W80H28,Применить,CALL FIX,
    LIST Win2_List3,L183T139W53H100,|ALL|BIOS|UEFI,,BIOS
    LABE Win2_LABE1,L50T62W43H17,Язык:,,
    LABE Win2_LABE2,L55T8W180H17,Выберите системный раздел:,,
    LABE Win2_LABE3,L15T111W180H18,Выбрать загрузочный раздел:,,
    LABE Win2_LABE4,L15T142W160H17,Укажите тип загрузки:,,
    LABE Win2_LABE5,L250T239W28H17,HELP,call fun3,0xff0000,
    ENVI @Win2_CHEK1.check=1
    ENVI @Win2_CHEK2.Enable=1
    ENVI @Win2_List3.Enable=0
    CALL @+ Fun1
    call FUN2
_END
_SUB llj  //MEMO
  ENVI @Win2_LABE3=%~1
find $%radi2.check%=1,
  {
    //envi @item4.enable=0
    FIND $X=X%~1, envi @Win1_item1.enable=0! EXEC* -code:UTF8 -err+ @MEMO1=!.\wimlib-imagex.exe info "%~1"
    LPOS &&iPos=Count,1,%MEMO1%
    calc #pos = %ipos% + 11
    LSTR &&ipos= %pos%,%MEMO1%
    RSTR &&ipos=2,%&ipos%
    envi &&i=1
    envi &&j=
    loop %&i%<=%&ipos%,
     {
        envi &j=%&j%%&i%|
        CALC &i= %&i% + 1
     TEAM envi @Win1_list3.VAL=%&j%| envi @Win1_list3.SEL=1
      }
  }
find $%radi1.check%=1,
  {
    FIND $X=X%~1, TEAM envi @Win1_item1.enable=0| envi @item4.enable=0! TEAM EXEC* -code:866 -err+ @MEMO1=!cmd.exe /c Dism /get-wiminfo /wimFile:"%~1" 2>&1 | envi @item4.enable=1
     read -,-1,&&pos,%MEMO1%
     calc #&&ipos = (%&pos% - 7)/5
     envi &&i=1
     envi &&j=
     loop %&i%<=%&ipos%,
     {
        envi &j=%&j%%&i%|
        CALC &i= %&i% + 1
     TEAM envi @Win1_list3.VAL=%&j%| envi @Win1_list3.SEL=1
      }
   }
_END